Recents in Beach


Receba o meu conteúdo GRATUITAMENTE


Automação com APP Fernando K



Se você quer aprender automação de maneira fácil, descomplicada e rápida, esse é o vídeo que você deve assistir hoje!

Criei uma biblioteca, que está registrada no site do Arduino, e, utilizando o App Fernando K no celular você pode controlar diversos sensores, relês, entre outras muitas coisas. Fiz um aplicativo próprio para garantir esse acesso, sem medo de usar um pronto e ele, de repente, deixar de existir. Sem contar que os aplicativos já existentes não dispõem de todos os tipos de customização que eu gostaria, e essa dificuldade foi apontada por muitos dos meus seguidores.

Então, confira aí como ligar e desligar um relê utilizando o App Fernando K e a sua biblioteca.

 


 

 

RECURSOS USADOS

  • ESP32 ou ESP8266
  • Protoboard
  • Jumpers
  • Relê



 

 

MONTAGEM


 

 

BIBLIOTECAS

App Fernando K

https://github.com/ferkoyanagi/AppFernandok

 

Na IDE do Arduino clique em Arquivo->Exemplos->App Fernando K->Relay



 

FLUXOGRAMA EXEMPLO



 

CÓDIGO

Declarações e variáveis

//Este exemplo cria um server na porta 80 para receber conexões de clients
//que podem enviar mensagens "relay on" para ligar o relê ou "relay off" para
//desligar o relê
#include <AppFernandoK.h>

//Pino onde está o relê
#define RELAY_PIN 2

//SSID e senha da rede WiFi. Modifique de acordo com a sua rede.
#define SSID "YOUR_SSID"
#define PASSWORD "YOUR_PASSWORD"

//Objeto que irá gerenciar as conexões com os clients
AppFernandoK app;

 

setup

void setup()
{
    Serial.begin(115200);

    //Colocamos o pino do relê como saída
    pinMode(RELAY_PIN, OUTPUT);

    //Desligamos o relê. Na configuração do nosso relê: HIGH desliga e LOW liga
    digitalWrite(RELAY_PIN, HIGH);

    //Conectamos à WiFi
    setupWiFi();

    //Inicializa um server para que os clients se conectem na porta 80
    app.beginWiFiServer(80);

    //Informamos qual função deverá ser executada quando algo chegar de algum client
    app.onMessage(onMessage);
}

 

setupWiFi

//Conecta à rede WiFi
void setupWiFi() 
{
    Serial.print("Connecting to WiFi");

    //Mandamos conectar à rede WiFi
    WiFi.begin(SSID, PASSWORD);

    //Enquanto não estiver conectado
    while (WiFi.status() != WL_CONNECTED)
    {
        //Espera 500ms
        Serial.print(".");
        delay(500);
    }

    //Se chegou aqui está conectado
    Serial.println("Connected!");

    //Mostra o IP para utilizarmos na conexão
    Serial.println(WiFi.localIP().toString());
}

 

loop

void loop()
{
    //Chamamos a função da lib que irá fazer as verificações necessárias (nova conexão, desconexão, nova mensagem)
    app.handleConnections();
}

 

onMessage

//Será executada toda fez que chegar algo dos clients
void onMessage(String message, IPAddress ip)
{
    //Exibe a mensagem e o IP de quem enviou
    Serial.print("Received message: ");
    Serial.print(message);
    Serial.print(" from ");
    Serial.println(ip.toString());

    //Remove eventuais espaços em branco
    message.trim();

    //Coloca a string toda em maiúsculo
    message.toUpperCase();

    //Se a mensagem que chegou for "RELAY ON"
    if(message == "RELAY ON")
    {
        //Liga o relê
        digitalWrite(RELAY_PIN, LOW);
        //Avisa para quem enviou a mensagem que tudo ocorreu bem
        app.sendMessage(message + " OK", ip);
        //Alternativamente se quiser enviar para todos os clients conectados:
        //app.sendMessageToAll(message + " OK");
    }
    else if(message == "RELAY OFF")
    {
        //Desliga o relê
        digitalWrite(RELAY_PIN, HIGH);
        //Avisa para quem enviou a mensagem que tudo ocorreu bem
        app.sendMessage(message + " OK", ip);
    }
    else
    {   
        //Se chegou aqui significa que a mensagem não era conhecida
        //Então avisamos quem enviou que a mensagem não foi reconhecida
        app.sendMessage("Unknown command: " + message, ip);
    }
}

 

 

 

APP FERNANDO K

https://play.google.com/store/apps/details?id=com.appfernandok

https://apps.apple.com/app/fernando-k/id1449589064

 




Adicione nome para a conexão, o IP  que o ESP mostra no monitor serial e a

porta. Clique em “Add”.


A conexão aparecerá  na lista. Clique nela.




Adicione um botão que irá ligar o relê com o seguinte código:


Adicione um botão que irá desligar o relê com o seguinte código:

 




Agora basta clicar no botão “on”. Quando quiser ligar o relê e no botão “off” quando quiser desligar




FAÇA O DOWNLOAD DOS ARQUIVOS:
PDF
INO

Postar um comentário

2 Comentários

  1. Bom dia ! Assisti até o final ( mais precisamente 34 minutos ... rsrs ) .... mais 1 vídeo de excelente conteúdo ! Parabéns pelos excelentes trabalhos que vc vem realizando através de seus vídeos !

    Admiro muito pelo o que vc vem realizando !


    Um grande abraço de

    Eng. Maurício Pereira.

    ResponderExcluir
  2. Perfeito como sempre!!!
    Fiquei até o final, pois, bons conteúdos é raro.Principalmente quando o apresentador é competente.Parabéns!!!

    ResponderExcluir